Useful zsh Init File Things

Click the below examples to enlarge them.

 1# ~/.zshrc
 2local curr_dir_file=~/.curr_dirs
 3upd_curr_dirs()
 4{
 5  rm_self_curr_dirs
 6  tty >/dev/null && printf '%-12s %s\n' $(tty) "$(print -P '%~')" \
 7    >>$curr_dir_file
 8}
 9add-zsh-hook chpwd upd_curr_dirs
10
11rm_self_curr_dirs()
12{
13  if tty >/dev/null
14  then
15    local newdirs=$(cat $curr_dir_file | grep -v "^$(tty)")
16    echo $newdirs >$curr_dir_file
17  fi
18}
19add-zsh-hook zshexit rm_self_curr_dirs
20
21select_saved_directory()
22{
23  cat $curr_dir_file | fzf | sed -E 's!^(.*) (/|~)!\2!g'
24}
25
26d()
27{
28  dir=$(select_saved_directory)
29  [[ -n $dir ]] && eval cd "$dir"
30}

I often find myself in the situation of having to open a new shell session (in a new terminal window or tmux pane) with the same current working directory as an existing session. This script makes jumping to the current working directory of an existing shell session easy. One need only type d, and a menu of other shell sessions and their working directories will be displayed. Selecting a directory and pressing Enter will change to that directory. When exiting a shell, the entry associated with that shell session will be cleared.

Typically, the ~/.curr_dirs file looks like this:

1/dev/pts/5   ~/docs/website
2/dev/pts/1   ~/code/projects/trt-dotfiles/desktops
3/dev/pts/9   ~/docs/website
4/dev/pts/3   ~/docs/website

Each line represents a shell session. The first component of each line represents the pseudoterminal associated with that session, while the second represents the current working directory of the session. It's theoretically possible to use the ~/.curr_dirs file to store directory bookmarks by making the first component a value that doesn't start with the name of a terminal and doesn't contain words starting with ~ or /. However, the system was not designed for this, nor have I used it this way.

A quick note on design: the use of an intermediate variable in rm_self_curr_dirs is necessary to prevent clearing the current directories file before reading it, as would happen if a pipeline read the file, processed it, and wrote back to it all at once. Ensuring that directories with spaces are handled properly is perilous when the file format used to store them separates records with spaces. Nonetheless, the code as written handles it correctly unless the terminals associated with each shell session (or whatever other "keys" there are) contain a space followed by a slash or a space followed by a tilde. This won't happen in normal operation.